TcxEditingControl.OnGetScrollbarAnnotationHint Event

Enables you to display hints for scrollbar annotations.

Declaration

property OnGetScrollbarAnnotationHint: TdxGetScrollbarAnnotationHint read; write;

Remarks

This event occurs every time the mouse pointer enters into the area occupied by one or more scrollbar annotation marks. Handle the OnGetScrollbarAnnotationHint event to display a hint for one or more of the triggered annotation marks. For example, the following code example shows a hint for the three custom scrollbar annotations and the predefined error annotation:

Delphi

procedure TMyForm.cxDBVerticalGrid1GetScrollbarAnnotationHint(Sender: TObject; AAnnotationRowIndexLists: TdxScrollbarAnnotationRowIndexLists; var AHint: string);
  function GetValue(ARecordIndex: Integer; AColumn: TcxDBEditorRow): Variant;  // Obtains the specified cell value
  begin
    Result := AColumn.Properties.Values[ARecordIndex];
  end;
var
  AKind: TdxScrollbarAnnotationKind;
  AList: TdxScrollbarAnnotationRowIndexList;
  I: Integer;
  ACount: Integer;
  AAnnotationHint: string;
begin
  for AKind in AAnnotationRowIndexLists.Keys do  // Iterates through all annotations that require a hint
  begin
    AList := AAnnotationRowIndexLists[AKind];
    ACount := Min(5, AList.Count);  // The number of processed scrollbar annotation marks is 5 or the number of triggered marks, whichever is less
    for I := 0 to ACount - 1 do  // Iterates through all scrollbar annotation marks to be processed
    begin
      case AKind of
        0:  // If the mouse pointer enters into the area occupied by a mark of the first custom scrollbar annotation
          begin
            AAnnotationHint := Format(' %s doors', [IntToStr(GetValue(AList[I], clDoorCount))]);
          end;
        1:  // If the mouse pointer enters into the area occupied by a mark of the second custom scrollbar annotation
          begin
            AAnnotationHint := Format('(price: %s)', [FormatFloat('$,0;($,0)', GetValue(AList[I], clPrice))]);
          end;
        2:  // If the mouse pointer enters into the area occupied by a mark of the third custom scrollbar annotation
          begin
            AAnnotationHint := Format(' %s cylinders', [IntToStr(GetValue(AList[I], clCilinderCount))]);
          end;
        dxErrorScrollbarAnnotationID:  // If the mouse pointer enters into the area occupied by a mark of the predefined error scrollbar annotation
          begin
            AAnnotationHint := ' - MPG City is not specified!';
          end;
      else  // If a scrollbar annotation requires no hint
        AAnnotationHint := '';  // Assigns an empty string as a base hint
      end;
      if AAnnotationHint <> '' then  // If the scrollbar annotation mark has a base hint
      begin  // Expands the base hint with content of the corresponding vertical grid column
        AAnnotationHint := Format('%s %s', [GetValue(AList[I], clName), GetValue(AList[I], clModification)]) + AAnnotationHint;
        AHint := AHint + IfThen(AHint <> '', dxCRLF) + AAnnotationHint;
      end;
    end;
    if AList.Count > ACount then  // If the list of hinted annotation marks is too large
      AHint := AHint + dxCRLF + Format('And %d more records...', [AList.Count - ACount]);  // Truncates the list
  end;
end;

C++

void __fastcall TMyForm::cxDBVerticalGrid1GetScrollbarAnnotationHint(TObject *Sender, TdxScrollbarAnnotationRowIndexLists *AAnnotationRowIndexLists, UnicodeString &AHint)
{
  System::DynamicArray<TdxScrollbarAnnotationKind> AKinds = AAnnotationRowIndexLists->Keys->ToArray();
  TdxScrollbarAnnotationKind AKind;
  int ACount;
  UnicodeString AAnnotationHint;
  TdxScrollbarAnnotationRowIndexList* AList;
  int ARecordIndex;
  for(int i = 0; i < AKinds.Length; i++)  // Iterates through all annotations that require a hint
  {
    AKind = AKinds[i];
    AAnnotationRowIndexLists->TryGetValue(AKind, AList);
    ACount = Math::Min(5, AList->Count);  // The number of processed scrollbar annotation marks is 5 or the number of triggered marks, whichever is less
    for(int j = 0; j < ACount; j++)  // Iterates through all scrollbar annotation marks to be processed
    {
      ARecordIndex = AList->Items[j];
      switch(AKind)
      {
        case 0:  // If the mouse pointer enters into the area occupied by a mark of the first custom scrollbar annotation
          AAnnotationHint = String::Format(" %s doors", ARRAYOFCONST((GetValue(ARecordIndex, clDoorCount))));
          break;
        case 1:  // If the mouse pointer enters into the area occupied by a mark of the second custom scrollbar annotation
        {
          float f = GetValue(ARecordIndex, clPrice);
          AAnnotationHint = " (price: " + FormatFloat("$,0;($,0)", f) + ")";
          break;
        }
        case 2:  // If the mouse pointer enters into the area occupied by a mark of the third custom scrollbar annotation
          AAnnotationHint = String::Format(" %s cylinders", ARRAYOFCONST((GetValue(ARecordIndex, clCilinderCount))));
          break;
        case dxErrorScrollbarAnnotationID:  // If the mouse pointer enters into the area occupied by a mark of the predefined error scrollbar annotation
          AAnnotationHint = " - MPG City is not specified!";
          break;
        default:  // If a scrollbar annotation requires no hint
          AAnnotationHint = "";  // Assigns an empty string as a base hint
      };
      if(AAnnotationHint != "")  // If the scrollbar annotation mark has a base hint
      {  // Expands the base hint with content of the corresponding vertical grid column
      AAnnotationHint = String::Format("%s %s%s", ARRAYOFCONST((GetValue(ARecordIndex, clName), GetValue(ARecordIndex, clModification), AAnnotationHint)));
      AHint = AHint + IfThen(AHint != "", dxCRLF) + AAnnotationHint;
      };
    };
    if(AList->Count > ACount)  // If the list of hinted annotation marks is too large
      AHint = AHint + dxCRLF + "And " + IntToStr(AList->Count - ACount) +  " more records...";  // Truncates the list
  };
}

Refer to the TdxGetScrollbarAnnotationHint procedural type description for detailed information on parameters accessible within an OnGetScrollbarAnnotationHint event handler.