DynamicListLookUpSettings Class

Provides the look-up editor settings for dashboard parameters that are bound to a data source.

Namespace: DevExpress.DashboardCommon

Assembly: DevExpress.Dashboard.v18.1.Core.dll

Syntax

public class DynamicListLookUpSettings :
    ParameterLookUpSettings

Use the DashboardParameter.LookUpSettings property to specify the look-up editor settings of the parameter.

Examples

The following example demonstrates how to create a new dashboard parameter and pass it to a dashboard item filter string.

In this example, the dashboard data source contains two queries - the SalesPerson query is used for data visualization while the Categories query provides values for the dashboard parameter. After the dashboard parameter is created, it is passed to a dashboard item's filter strings. So, the dashboard displays data according to the selected values.

´╗┐Imports DevExpress.XtraEditors
Imports DevExpress.DashboardCommon

Namespace Dashboard_Parameters
    Partial Public Class Form1
        Inherits XtraForm

        Public Sub New()
            InitializeComponent()

            ' Loads a dashboard from an XML file.
            Dim dashboard As New Dashboard()
            dashboard.LoadFromXml("..\..\Data\Dashboard.xml")

            ' Obtains dashboard items and specifies idenifiers for required data items.
            Dim grid As GridDashboardItem = CType(dashboard.Items(0), GridDashboardItem)
            Dim pie As PieDashboardItem = CType(dashboard.Items(1), PieDashboardItem)
            CType(grid.Columns(0), GridDimensionColumn).Dimension.UniqueId = "categoryColumn"
            pie.SeriesDimensions(0).UniqueId = "categorySeries"

            ' Obtains the dashboard data source used to provide parameter values.
            Dim parameterDataSource As DashboardSqlDataSource =
                CType(dashboard.DataSources(0), DashboardSqlDataSource)

            ' Creates a new parameter that obtains its values from the Categories query.
            Dim settings As New DynamicListLookUpSettings()
            settings.DataSource = parameterDataSource
            settings.DataMember = "Categories"
            settings.ValueMember = "CategoryName"
            Dim parameter As New DashboardParameter("categoryParameter", GetType(String), _
                                                    "Beverages", "Select categories:", True, settings)
            ' Enables multi-selection for the created parameter.
            parameter.AllowMultiselect = True

            ' Adds the created parameter to a collection of dashboard parameters.
            dashboard.Parameters.Add(parameter)

            ' Includes the created parameter in filter strings as an operand value.
            grid.FilterString = "categoryColumn in (?categoryParameter)"
            pie.FilterString = "categorySeries in (?categoryParameter)"

            dashboardViewer1.Dashboard = dashboard
        End Sub
    End Class
End Namespace

Inheritance

Object
ParameterLookUpSettings
DynamicListLookUpSettings

See Also