TdxReport.ExportFormats Property

Specifies export formats available in the Report Viewer dialog.

Declaration

property ExportFormats: TdxReportExportFormats read; write; default AllReportExportFormats;

Property Value

Type	Default	Description
TdxReportExportFormats	AllReportExportFormats	The set of flags that correspond to individual supported export formats.

Remarks

The Web-based Report Viewer dialog lists multiple export formats and corresponding settings available to users.

You can use the ExportFormats property to change the list of available export formats.

Code Example: Populate Templates and Export Reports

This code example loads an XML-based report template (REPX) from a dataset, configures export settings, populates the template with data from another dataset, and displays the report preview:

Delphi

uses
  dxReport,  // Declares the TdxReport component and related types
  dxReport.ConnectionString.JSON.DB;  // Declares the TdxReportDataSetJSONConnection component
// ...

procedure TMyForm.Button1Click(Sender: TObject);
var
  ADataConnection: TdxReportDataSetJSONConnection;
  AReport: TdxReport;
  ALayoutStream: TStream;
begin
  ADataConnection := TdxReportDataSetJSONConnection.Create(Self);
  try
    ADataConnection.Name := 'DataSetJSONData';
    ADataConnection.DataSets.Add('Data', FDataSet);
    AReport := TdxReport.Create(Self);
    try
      AReport.ReportName := 'Report';
      ALayoutStream := FLayoutDataSet.CreateBlobStream(FLayoutDataSet.FieldByName('Layout'), bmRead);
      try
        AReport.Layout.LoadFromStream(ALayoutStream);
      finally
        ALayoutStream.Free;
      end;
      AReport.Language := 'fr-FR';
      AReport.ExportFormats := [TdxReportExportFormat.PDF,
        TdxReportExportFormat.RTF, TdxReportExportFormat.HTML];
      AReport.FilterString := 'id = 5';
      AReport.ShowViewer;
    finally
      AReport.Free;
    end;
  finally
    ADataConnection.Free;
  end;
end;

C++

#include "dxReport.hpp"  // Declares the TdxReport component and related types
#include "dxReport.ConnectionString.JSON.DB.hpp" // Declares the TdxReportDataSetJSONConnection component

// Add the following linker directives to the corresponding CPP source file:
#pragma link "dxReport"  // Required to use dxReport.hpp declarations
#pragma link "dxReport.ConnectionString.JSON.DB" //Required to use TdxReportDataSetJSONConnection declarations
// ...

void __fastcall TMyForm::Button1Click(TObject *Sender)
{
  TdxReportDataSetJSONConnection *ADataConnection;
  TdxReport *AReport;
  TStream *ALayoutStream;
  ADataConnection = new TdxReportDataSetJSONConnection(this);
  try
  {
    ADataConnection->Name = "DataSetJSONData";
    ADataConnection->DataSets->Add("Data", FDataSet);
    AReport = new TdxReport(this);
    try
    {
      AReport->ReportName = "Report";
      ALayoutStream = FLayoutDataSet->CreateBlobStream(FLayoutDataSet->FieldByName("Layout"), bmRead);
      try
      {
        AReport->Layout->LoadFromStream(ALayoutStream);
      }
      __finally
      {
        delete ALayoutStream;
      }
      AReport->Language = "fr-FR";
      AReport->ExportFormats = TdxReportExportFormats() << TdxReportExportFormat::PDF
        << TdxReportExportFormat::RTF << TdxReportExportFormat::HTML;
      AReport->FilterString = "id = 5";
      AReport->ShowViewer();
    }
    __finally
    {
      delete AReport;
    }
  }
  __finally
  {
    delete ADataConnection;
  }
}

Default Value

The ExportFormats property’s default value is the AllReportExportFormats global constant.