TdxReportExportFormat Enum

Enumerates formats available for report export operations.

Declaration

TdxReportExportFormat = (
    CSV,
    DOCX,
    HTML,
    Image,
    MHT,
    PDF,
    RTF,
    Text,
    XLS,
    XLSX
);

Members

Name	Description	Format-Specific Export Method
CSV	Comma-Separated Values (CSV)	TdxReport.ExportToCSV
DOCX	Office Open XML Document (DOCX)	TdxReport.ExportToDOCX
HTML	Hypertext Markup Language (HTML)	TdxReport.ExportToHTML
Image	Image Export Format. The actual image format depends on Image Export Options available in the Report Viewer dialog (the default image export format is PNG).	TdxReport.ExportToImage
MHT	MIME HTML Document Format (MHT/MHTML)	TdxReport.ExportToMHT
PDF	Portable Document Format (PDF)	TdxReport.ExportToPDF
RTF	Rich Text Format (RTF)	TdxReport.ExportToRTF
Text	Plain text format (TXT)	TdxReport.ExportToText
XLS	Microsoft Excel® Binary Format (XLS)	TdxReport.ExportToXLS
XLSX	Office Open XML Spreadsheet Format (XLSX)	TdxReport.ExportToXLSX

Remarks

The Web-based Report Viewer dialog lists multiple export formats and corresponding settings available to users:

Users can configure each available export format in the Export Options pane.

Note

TdxReportExportFormat is a scoped enumeration type. Use the type name together with a scope resolution token (. in Delphi or :: in C++Builder) followed by an enumeration value to refer to this value. For example, use TdxReportExportFormat.XLSX (in Delphi) or TdxReportExportFormat::XLSX (in C++Builder) to refer to the XLSX value in code.

Code Example: Load and Populate Report Templates from Datasets

This code example loads an XML-based report template (REPX) from a dataset, configures export settings, populates the template with data from another dataset, and displays the report preview:

Delphi

uses
  dxReport,  // Declares the TdxReport component and related types
  dxReport.ConnectionString.JSON.DB;  // Declares the TdxReportDataSetJSONConnection component
// ...

procedure TMyForm.Button1Click(Sender: TObject);
var
  ADataConnection: TdxReportDataSetJSONConnection;
  AReport: TdxReport;
  ALayoutStream: TStream;
begin
  ADataConnection := TdxReportDataSetJSONConnection.Create(Self);
  try
    ADataConnection.Name := 'DataSetJSONData';
    ADataConnection.DataSets.Add('Data', FDataSet);
    AReport := TdxReport.Create(Self);
    try
      AReport.ReportName := 'Report';
      ALayoutStream := FLayoutDataSet.CreateBlobStream(FLayoutDataSet.FieldByName('Layout'), bmRead);
      try
        AReport.Layout.LoadFromStream(ALayoutStream);
      finally
        ALayoutStream.Free;
      end;
      AReport.Language := 'fr-FR';
      AReport.ExportFormats := [TdxReportExportFormat.PDF,
        TdxReportExportFormat.RTF, TdxReportExportFormat.HTML];
      AReport.FilterString := 'id = 5';
      AReport.ShowViewer;
    finally
      AReport.Free;
    end;
  finally
    ADataConnection.Free;
  end;
end;

C++

#include "dxReport.hpp"  // Declares the TdxReport component and related types
#include "dxReport.ConnectionString.JSON.DB.hpp" // Declares the TdxReportDataSetJSONConnection component

// Add the following linker directives to the corresponding CPP source file:
#pragma link "dxReport"  // Required to use dxReport.hpp declarations
#pragma link "dxReport.ConnectionString.JSON.DB" //Required to use TdxReportDataSetJSONConnection declarations
// ...

void __fastcall TMyForm::Button1Click(TObject *Sender)
{
  TdxReportDataSetJSONConnection *ADataConnection;
  TdxReport *AReport;
  TStream *ALayoutStream;
  ADataConnection = new TdxReportDataSetJSONConnection(this);
  try
  {
    ADataConnection->Name = "DataSetJSONData";
    ADataConnection->DataSets->Add("Data", FDataSet);
    AReport = new TdxReport(this);
    try
    {
      AReport->ReportName = "Report";
      ALayoutStream = FLayoutDataSet->CreateBlobStream(FLayoutDataSet->FieldByName("Layout"), bmRead);
      try
      {
        AReport->Layout->LoadFromStream(ALayoutStream);
      }
      __finally
      {
        delete ALayoutStream;
      }
      AReport->Language = "fr-FR";
      AReport->ExportFormats = TdxReportExportFormats() << TdxReportExportFormat::PDF
        << TdxReportExportFormat::RTF << TdxReportExportFormat::HTML;
      AReport->FilterString = "id = 5";
      AReport->ShowViewer();
    }
    __finally
    {
      delete AReport;
    }
  }
  __finally
  {
    delete ADataConnection;
  }
}

Direct TdxReportExportFormat Type References

The following public APIs reference the TdxReportExportFormats type:

AllReportExportFormats

A set of flags that correspond to all export data formats available for the TdxReport component.

TdxReportExportFormats

A set of flags that correspond to report data export formats.

TdxReportExportFormat Type References in Method Parameters

The following export methods accept a TdxReportExportFormat value as the AFormat parameter:

TdxReport.ExportTo

Exports report content to a stream in any supported format.

TdxReport.StartExportAsync

Starts an asynchronous report export operation (in the specified format).